| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | blackberry { |
|---|
| 23 | # DEFINES += QT_NO_SHORTCUT |
|---|
| 24 | DEFINES += QT_NO_PRINTDIALOG |
|---|
| 25 | DEFINES += QT_NO_PRINTPREVIEWDIALOG |
|---|
| 26 | } |
|---|
| 27 | |
|---|
| 28 | TEMPLATE = app |
|---|
| 29 | |
|---|
| 30 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 31 | |
|---|
| 32 | # Version information |
|---|
| 33 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 34 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 35 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 36 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2011 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 37 | |
|---|
| 38 | # Versioning |
|---|
| 39 | BUILD_VERSION_MAJOR = 0 |
|---|
| 40 | BUILD_VERSION_MINOR = 1 |
|---|
| 41 | BUILD_RELEASE = 4 |
|---|
| 42 | |
|---|
| 43 | # These are only defined on releases |
|---|
| 44 | DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 45 | DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 46 | DEFINES += BUILD_STATUS_NUMBER=2 |
|---|
| 47 | |
|---|
| 48 | REVISION = 170 |
|---|
| 49 | isEmpty(REVISION) { |
|---|
| 50 | REVISION = $$system(svnversion) |
|---|
| 51 | } |
|---|
| 52 | isEmpty(REVISION)|isEqual(REVISION,exported) { |
|---|
| 53 | REVISION = 0 |
|---|
| 54 | } else { |
|---|
| 55 | REVISION = $$replace(REVISION,":","") |
|---|
| 56 | REVISION = $$replace(REVISION,"M","") |
|---|
| 57 | } |
|---|
| 58 | SHORT_VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 59 | win32-msvc*|wincewm* { |
|---|
| 60 | VERSION = $$SHORT_VERSION |
|---|
| 61 | } else { |
|---|
| 62 | VERSION = $$sprintf("%1.%2",$$SHORT_VERSION,$$BUILD_RELEASE) |
|---|
| 63 | } |
|---|
| 64 | |
|---|
| 65 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 66 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 67 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 68 | BUILD_NUMBER=$$REVISION |
|---|
| 69 | |
|---|
| 70 | blackberry { |
|---|
| 71 | TARGET = tspsg |
|---|
| 72 | } else { |
|---|
| 73 | CONFIG(release, debug|release) { |
|---|
| 74 | OBJECTS_DIR = release |
|---|
| 75 | D = |
|---|
| 76 | } else { |
|---|
| 77 | OBJECTS_DIR = debug |
|---|
| 78 | DEFINES += DEBUG |
|---|
| 79 | # CONFIG += console |
|---|
| 80 | D = d |
|---|
| 81 | } |
|---|
| 82 | DESTDIR = bin |
|---|
| 83 | TARGET = tspsg$${D} |
|---|
| 84 | } |
|---|
| 85 | |
|---|
| 86 | # Saving all intermediate files to tmp directory. |
|---|
| 87 | MOC_DIR = tmp |
|---|
| 88 | RCC_DIR = tmp |
|---|
| 89 | UI_DIR = tmp |
|---|
| 90 | |
|---|
| 91 | # Include 3rd party libraries |
|---|
| 92 | !handheld { |
|---|
| 93 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 94 | } |
|---|
| 95 | |
|---|
| 96 | win32:LIBS += -lole32 |
|---|
| 97 | |
|---|
| 98 | # Include file(s) |
|---|
| 99 | include(tspsg.pri) |
|---|
| 100 | |
|---|
| 101 | # Installation and deployment rules |
|---|
| 102 | include(install.pri) |
|---|
