| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 145 2010-10-15 06:15:43Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/tags/0.1.3.145-beta1/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | TEMPLATE = app |
|---|
| 24 | |
|---|
| 25 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 26 | |
|---|
| 27 | # Version information |
|---|
| 28 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 29 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 30 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 31 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2010 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 32 | |
|---|
| 33 | # Versioning |
|---|
| 34 | BUILD_VERSION_MAJOR = 0 |
|---|
| 35 | BUILD_VERSION_MINOR = 1 |
|---|
| 36 | BUILD_RELEASE = 3 |
|---|
| 37 | |
|---|
| 38 | # These are only defined on releases |
|---|
| 39 | DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 40 | DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 41 | DEFINES += BUILD_STATUS_NUMBER=1 |
|---|
| 42 | |
|---|
| 43 | REVISION = 145 |
|---|
| 44 | #REVISION = $$system(svnversion) |
|---|
| 45 | #isEmpty(REVISION)|eval(REVISION=="exported") { |
|---|
| 46 | # REVISION = 0 |
|---|
| 47 | #} else { |
|---|
| 48 | # REVISION = $$replace(REVISION,":","") |
|---|
| 49 | # REVISION = $$replace(REVISION,"M","") |
|---|
| 50 | #} |
|---|
| 51 | win32-msvc*|wincewm* { |
|---|
| 52 | VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 53 | } else { |
|---|
| 54 | VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 55 | } |
|---|
| 56 | |
|---|
| 57 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 58 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 59 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 60 | BUILD_NUMBER=$$REVISION |
|---|
| 61 | |
|---|
| 62 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 63 | macx { |
|---|
| 64 | PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl |
|---|
| 65 | } else:symbian { |
|---|
| 66 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 67 | } else:unix { |
|---|
| 68 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 69 | } else { |
|---|
| 70 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 71 | } |
|---|
| 72 | include($$join(PRL, "/")) |
|---|
| 73 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 74 | # We "embed" SVG icon support on static build |
|---|
| 75 | DEFINES += STATIC_BUILD |
|---|
| 76 | # !nosvg:QTPLUGIN += qsvgicon |
|---|
| 77 | } |
|---|
| 78 | |
|---|
| 79 | CONFIG(release, debug|release) { |
|---|
| 80 | OBJECTS_DIR = release |
|---|
| 81 | D = |
|---|
| 82 | } else { |
|---|
| 83 | OBJECTS_DIR = debug |
|---|
| 84 | DEFINES += DEBUG |
|---|
| 85 | # CONFIG += console |
|---|
| 86 | D = d |
|---|
| 87 | } |
|---|
| 88 | DESTDIR = bin |
|---|
| 89 | TARGET = tspsg$${D} |
|---|
| 90 | |
|---|
| 91 | # Saving all intermediate files to tmp directory. |
|---|
| 92 | MOC_DIR = tmp |
|---|
| 93 | RCC_DIR = tmp |
|---|
| 94 | UI_DIR = tmp |
|---|
| 95 | |
|---|
| 96 | # Include 3rd party libraries |
|---|
| 97 | !handheld { |
|---|
| 98 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 99 | } |
|---|
| 100 | |
|---|
| 101 | win32:LIBS += -lole32 |
|---|
| 102 | |
|---|
| 103 | # Include file(s) |
|---|
| 104 | include(tspsg.pri) |
|---|
| 105 | |
|---|
| 106 | # Installation and deployment |
|---|
| 107 | include(install.pri) |
|---|
