| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | TEMPLATE = app |
|---|
| 20 | |
|---|
| 21 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 22 | |
|---|
| 23 | # Versioning |
|---|
| 24 | BUILD_VERSION_MAJOR = 0 |
|---|
| 25 | BUILD_VERSION_MINOR = 1 |
|---|
| 26 | BUILD_RELEASE = 3 |
|---|
| 27 | |
|---|
| 28 | # These are only defined on releases |
|---|
| 29 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 30 | #!symbian { |
|---|
| 31 | # DEFINES += BUILD_STATUS="\"(alpha 2)\"" |
|---|
| 32 | #} else { |
|---|
| 33 | # # Symbian doesn't handle spaces in defines well |
|---|
| 34 | # DEFINES += BUILD_STATUS="(alpha2)" |
|---|
| 35 | #} |
|---|
| 36 | |
|---|
| 37 | #REVISION = 100 |
|---|
| 38 | REVISION = $$system(svnversion) |
|---|
| 39 | REVISION = $$replace(REVISION,":","") |
|---|
| 40 | REVISION = $$replace(REVISION,"M","") |
|---|
| 41 | win32-msvc*|wincewm* { |
|---|
| 42 | VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 43 | } else { |
|---|
| 44 | VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 45 | } |
|---|
| 46 | |
|---|
| 47 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 48 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 49 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 50 | BUILD_NUMBER=$$REVISION |
|---|
| 51 | |
|---|
| 52 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 53 | macx { |
|---|
| 54 | PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl |
|---|
| 55 | } else:symbian { |
|---|
| 56 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 57 | } else:unix { |
|---|
| 58 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 59 | } else { |
|---|
| 60 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 61 | } |
|---|
| 62 | include($$join(PRL, "/")) |
|---|
| 63 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 64 | # We "embed" SVG icon, JPEG and TIFF support on static build |
|---|
| 65 | DEFINES += STATIC_BUILD |
|---|
| 66 | # QTPLUGIN += qjpeg qtiff |
|---|
| 67 | # !nosvg:QTPLUGIN += qsvgicon |
|---|
| 68 | } |
|---|
| 69 | |
|---|
| 70 | CONFIG(release, debug|release) { |
|---|
| 71 | OBJECTS_DIR = release |
|---|
| 72 | DESTDIR = release |
|---|
| 73 | D = |
|---|
| 74 | } else { |
|---|
| 75 | OBJECTS_DIR = debug |
|---|
| 76 | DESTDIR = debug |
|---|
| 77 | DEFINES += DEBUG |
|---|
| 78 | # CONFIG += console |
|---|
| 79 | D = d |
|---|
| 80 | } |
|---|
| 81 | TARGET = tspsg$${D} |
|---|
| 82 | |
|---|
| 83 | # Saving all intermediate files to tmp directory. |
|---|
| 84 | MOC_DIR = ./tmp |
|---|
| 85 | RCC_DIR = ./tmp |
|---|
| 86 | UI_DIR = ./tmp |
|---|
| 87 | |
|---|
| 88 | # Include 3rd party libraries |
|---|
| 89 | !wincewm*:!symbian { |
|---|
| 90 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 91 | } |
|---|
| 92 | |
|---|
| 93 | win32:LIBS += -lole32 |
|---|
| 94 | |
|---|
| 95 | # Include file(s) |
|---|
| 96 | include(tspsg.pri) |
|---|
| 97 | |
|---|
| 98 | # Installation and deployment |
|---|
| 99 | include(install.pri) |
|---|
