source: tspsg/tspsg.pro @ d45b48efe9

0.1.3.145-beta1-symbian
Last change on this file since d45b48efe9 was d45b48efe9, checked in by Oleksii Serdiuk, 13 years ago

Initial Symbian port.

Version 0.1.3.145-beta1, as published in the Nokia Ovi Store.

  • Property mode set to 100644
File size: 2.5 KB
Line 
1######################################################################
2#
3#  TSPSG: TSP Solver and Generator
4#  Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name>
5#
6#  $Id$
7#  $URL$
8#
9#  This file is part of TSPSG.
10#
11######################################################################
12
13!nosvg {
14        QT += svg
15} else {
16        DEFINES += NOSVG
17}
18
19wincewm*|symbian|maemo*|simulator {
20        CONFIG += handheld
21}
22
23TEMPLATE = app
24
25# QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk
26
27# Version information
28QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk
29QMAKE_TARGET_PRODUCT = TSP Solver and Generator
30QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator
31QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2010 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name>
32
33# Versioning
34BUILD_VERSION_MAJOR = 0
35BUILD_VERSION_MINOR = 1
36BUILD_RELEASE = 3
37
38# These are only defined on releases
39DEFINES += TSPSG_RELEASE_BUILD
40DEFINES += BUILD_STATUS_TYPE=beta
41DEFINES += BUILD_STATUS_NUMBER=1
42
43REVISION = 145
44#REVISION = $$system(svnversion)
45#isEmpty(REVISION)|eval(REVISION=="exported") {
46#       REVISION = 0
47#} else {
48#       REVISION = $$replace(REVISION,":","")
49#       REVISION = $$replace(REVISION,"M","")
50#}
51win32-msvc*|wincewm* {
52        VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR)
53} else {
54        VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION)
55}
56
57DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \
58        BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \
59        BUILD_RELEASE=$$BUILD_RELEASE \
60        BUILD_NUMBER=$$REVISION
61
62# A hack to determine whether we have static or dynamic Qt build
63macx {
64        PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl
65} else:symbian {
66#       PRL = $$[QT_INSTALL_LIBS] QtCore.prl
67} else:unix {
68        PRL = $$[QT_INSTALL_LIBS] libQtCore.prl
69} else {
70        PRL = $$[QT_INSTALL_LIBS] QtCore.prl
71}
72!isEmpty(PRL) {
73        include($$join(PRL, "/"))
74        contains(QMAKE_PRL_CONFIG, static) {
75                # We "embed" SVG icon support on static build
76                DEFINES += STATIC_BUILD
77#               !nosvg:QTPLUGIN += qsvgicon
78        }
79}
80
81CONFIG(release, debug|release) {
82        OBJECTS_DIR = release
83        D =
84} else {
85        OBJECTS_DIR = debug
86        DEFINES += DEBUG
87#       CONFIG += console
88        D = d
89}
90DESTDIR = bin
91TARGET = tspsg$${D}
92
93# Saving all intermediate files to tmp directory.
94MOC_DIR = tmp
95RCC_DIR = tmp
96UI_DIR = tmp
97
98# Include 3rd party libraries
99!handheld {
100        include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri)
101}
102
103win32:LIBS += -lole32
104
105# Include file(s)
106include(tspsg.pri)
107
108# Installation and deployment
109include(install.pri)
Note: See TracBrowser for help on using the repository browser.