source: tspsg/install.pri

appveyor
Last change on this file was b9167cec6d, checked in by leppa, 16 months ago

Update copyright years

  • Property mode set to 100644
File size: 5.4 KB
Line 
1######################################################################
2#
3#  TSPSG: TSP Solver and Generator
4#  Copyright (C) 2007-2016 Oleksii Serdiuk <contacts[at]oleksii[dot]name>
5#
6#  $Id: $Format:%h %ai %an$ $
7#  $URL: http://tspsg.info/ $
8#
9#  This file is part of TSPSG.
10#
11######################################################################
12
13# Common rules
14#l10n.files = l10n/*.qm
15#share.files =
16docs.files = COPYING ChangeLog.md README.md INSTALL.md
17INSTALLS += target docs # share l10n
18
19# For *nix:
20#   - executable goes to /usr/bin
21#   - translations go to /usr/share/TSPSG/l10n
22#   - COPYING, ChangeLog.md, README.md and INSTALL.md
23#     go to /usr/share/doc/TSPSG-x.x.x
24unix:!macx:!symbian:!maemo* {
25    isEmpty(PREFIX) {
26        PREFIX = /usr
27    }
28    CONFIG(release, debug|release) {
29        DEFINES += PATH_L10N=\\\"$$PREFIX/share/TSPSG/l10n\\\"
30        DEFINES += PATH_DOCS=\\\"$$PREFIX/share/TSPSG/docs\\\"
31    }
32
33    target.path = $$PREFIX/bin
34    share.path = $$PREFIX/share/TSPSG
35#       l10n.path = $$PREFIX/share/TSPSG/l10n
36    docs.path = $$PREFIX/share/doc/TSPSG-$$SHORT_VERSION
37    desktop.files = resources/tspsg.desktop
38    desktop.path = $$PREFIX/share/applications
39    icon.files = resources/tspsg.png
40    icon.path = $$PREFIX/share/pixmaps
41    INSTALLS += desktop icon
42}
43
44# TODO: MacOSX
45macx {
46}
47
48wince* {
49    # For wince: we are deploying to %CSIDL_PROGRAM_FILES%\TSPSG.
50    # This is automatically set by qmake when creating VS Solution file.
51    share.sources = $$share.files
52    l10n.sources = $$l10n.files \
53        $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \
54        $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm
55    docs.sources = $$docs.files
56
57    DEPLOYMENT += target share l10n docs
58    DEPLOYMENT_PLUGIN += qjpeg qtiff
59} else:win32 {
60    # For win32: everything goes to "%PROGRAMFILES%\TSPSG" and subfolders.
61    isEmpty(PREFIX) {
62        PREFIX = "$$(PROGRAMFILES)/TSPSG"
63    }
64
65    share.files = $$[QT_INSTALL_BINS]/QtCore$${D}4.dll \
66        $$[QT_INSTALL_BINS]/QtGui$${D}4.dll
67    !nosvg {
68        share.files += $$[QT_INSTALL_BINS]/QtSvg$${D}4.dll
69    }
70    l10n.files += $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \
71        $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm
72    win32-g++ {
73        share.files += $$[QT_INSTALL_BINS]/mingwm10.dll \
74            $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll
75    }
76    imageformats.files = $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${D}4.dll \
77        $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${D}4.dll
78    INSTALLS += share l10n imageformats
79
80    target.path = $$PREFIX
81    share.path = $$PREFIX
82    l10n.path = $$PREFIX/l10n
83    imageformats.path = $$PREFIX/imageformats
84    docs.path = $$PREFIX
85}
86
87# Symbian
88symbian {
89    TARGET = TSPSG$${D}
90
91    share.sources = $$share.files
92    # qmake for Symbian (as of Qt 4.6.2) has a bug: file masks don't work, so we need to specify all files manually
93#       l10n.sources = $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \
94#               $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm \
95#               l10n/tspsg_en.qm l10n/tspsg_ru.qm l10n/tspsg_uk.qm
96#       l10n.path = l10n
97    docs.sources = $$docs.files
98#       docs.pkg_prerules = \
99#               "\"README.txt\" - \"\", FILETEXT, TEXTCONTINUE" \
100#               "\"COPYING\" - \"\", FILETEXT, TEXTEXIT"
101    DEPLOYMENT += share docs # l10n
102#       DEPLOYMENT_PLUGIN += qjpeg qtiff qsvgicon
103
104    ICON = resources/tspsg.svg
105    TARGET.EPOCHEAPSIZE = 0x20000 0x1100000
106    # OVI Publish - 0x2003AEFB, Self-signed - 0xA89FD7A3
107    ovi_publish {
108        TARGET.UID3 = 0x2003AEFB
109    } else {
110        TARGET.UID3 = 0xA89FD7A3
111    }
112
113    languages="&EN,RU,UK"
114    package_header = "$$LITERAL_HASH{" \
115        " \"$$QMAKE_TARGET_PRODUCT\"," \
116        " \"$$QMAKE_TARGET_PRODUCT\"," \
117        " \"$$QMAKE_TARGET_PRODUCT\"" \
118        "},($$TARGET.UID3),$$BUILD_VERSION_MAJOR,$${BUILD_VERSION_MINOR}$${BUILD_RELEASE},$$BUILD_NUMBER"
119    vendor = \
120        "%{\"Oleksii Serdiuk\",\"Алексей Сердюк\",\"Олексій Сердюк\"}" \
121        ":\"Oleksii Serdiuk\""
122#       logo = \
123#               "=\"resources/tspsg.png\",\"image/png\",\"\""
124    dependencies = \
125        "; Depend on Qt $${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}" \
126        "(0x2001E61C),$${QT_MAJOR_VERSION},$${QT_MINOR_VERSION},$${QT_PATCH_VERSION},{\"Qt\",\"Qt\",\"Qt\"}" \
127        "; Declare the supported platforms" \
128        "; Symbian^1" \
129        "[0x1028315F],0,0,0,{\"S60ProductID\",\"S60ProductID\",\"S60ProductID\"}" \
130        "; Symbian^3" \
131        "[0x20022E6D],0,0,0,{\"S60ProductID\",\"S60ProductID\",\"S60ProductID\"}"
132
133    default_deployment.pkg_prerules -= pkg_platform_dependencies pkg_depends_qt
134    default_deployment.pkg_prerules += languages package_header vendor dependencies
135#       default_deployment.pkg_prerules += languages package_header vendor logo dependencies
136    # OVI Publish - 0x2002CCCF, Self-signed - 0xA000D7CE
137    ovi_publish {
138        SMARTINSTALLER_UID = 0x2002CCCF
139    } else {
140        SMARTINSTALLER_UID = 0xA000D7CE
141    }
142    DEPLOYMENT.installer_header = "$${LITERAL_HASH}{" \
143        "\"$$QMAKE_TARGET_PRODUCT Installer\"," \
144        "\"Установщик $$QMAKE_TARGET_PRODUCT\"," \
145        "\"Встановлювач $$QMAKE_TARGET_PRODUCT\"" \
146        "},($${SMARTINSTALLER_UID}),$$BUILD_VERSION_MAJOR,$${BUILD_VERSION_MINOR}$${BUILD_RELEASE},$$BUILD_NUMBER"
147}
148
149# Maemo 5
150maemo5 {
151    target.path = /opt/usr/bin
152    desktop.files = qtc_packaging/tspsg.desktop
153    desktop.path = /usr/share/applications/hildon
154    icon.files = qtc_packaging/tspsg.png
155    icon.path = /usr/share/icons/hicolor/64x64/apps
156
157    INSTALLS += desktop icon
158}
Note: See TracBrowser for help on using the repository browser.