source: tspsg-svn/trunk/tspsg.pro @ 141

Last change on this file since 141 was 141, checked in by laleppa, 13 years ago

+ Added support for Simulator from Nokia Qt SDK

  • Made some Maemo related tweaks
  • Removed ids for unsupported OSs from os.h (i.e., MSDOS, OS/2)
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id URL
File size: 2.5 KB
Line 
1######################################################################
2#
3#  TSPSG: TSP Solver and Generator
4#  Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name>
5#
6#  $Id: tspsg.pro 141 2010-10-03 12:01:00Z laleppa $
7#  $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $
8#
9#  This file is part of TSPSG.
10#
11######################################################################
12
13!nosvg {
14        QT += svg
15} else {
16        DEFINES += NOSVG
17}
18
19wincewm*|symbian|maemo*|simulator {
20        CONFIG += handheld
21}
22
23TEMPLATE = app
24
25# QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk
26
27# Version information
28QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk
29QMAKE_TARGET_PRODUCT = TSP Solver and Generator
30QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator
31QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2010 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name>
32
33# Versioning
34BUILD_VERSION_MAJOR = 0
35BUILD_VERSION_MINOR = 1
36BUILD_RELEASE = 3
37
38# These are only defined on releases
39#DEFINES += TSPSG_RELEASE_BUILD
40#!symbian {
41#       DEFINES += BUILD_STATUS="\"(alpha 2)\""
42#} else {
43#       # Symbian doesn't handle spaces in defines well
44#       DEFINES += BUILD_STATUS="(alpha2)"
45#}
46
47#REVISION = 100
48REVISION = $$system(svnversion)
49REVISION = $$replace(REVISION,":","")
50REVISION = $$replace(REVISION,"M","")
51win32-msvc*|wincewm* {
52        VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR)
53} else {
54        VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION)
55}
56
57DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \
58        BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \
59        BUILD_RELEASE=$$BUILD_RELEASE \
60        BUILD_NUMBER=$$REVISION
61
62# A hack to determine whether we have static or dynamic Qt build
63macx {
64        PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl
65} else:symbian {
66        PRL = $$[QT_INSTALL_LIBS] QtCore.prl
67} else:unix {
68        PRL = $$[QT_INSTALL_LIBS] libQtCore.prl
69} else {
70        PRL = $$[QT_INSTALL_LIBS] QtCore.prl
71}
72include($$join(PRL, "/"))
73contains(QMAKE_PRL_CONFIG, static) {
74        # We "embed" SVG icon, JPEG and TIFF support on static build
75        DEFINES += STATIC_BUILD
76#       !nosvg:QTPLUGIN += qsvgicon
77}
78
79CONFIG(release, debug|release) {
80        OBJECTS_DIR = release
81        D =
82} else {
83        OBJECTS_DIR = debug
84        DEFINES += DEBUG
85#       CONFIG += console
86        D = d
87}
88DESTDIR = bin
89TARGET = tspsg$${D}
90
91# Saving all intermediate files to tmp directory.
92MOC_DIR = tmp
93RCC_DIR = tmp
94UI_DIR = tmp
95
96# Include 3rd party libraries
97!handheld {
98        include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri)
99}
100
101win32:LIBS += -lole32
102
103# Include file(s)
104include(tspsg.pri)
105
106# Installation and deployment
107include(install.pri)
Note: See TracBrowser for help on using the repository browser.