source: tspsg-svn/trunk/install.pri @ 142

Last change on this file since 142 was 142, checked in by laleppa, 13 years ago

+ Added Online Support... and Report a Bug... menu entries.

  • Some insignificant adjustments to the code.
File size: 3.3 KB
Line 
1######################################################################
2#
3#  TSPSG: TSP Solver and Generator
4#  Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name>
5#
6#  $Id: install.pri 142 2010-10-05 19:44:54Z laleppa $
7#  $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/install.pri $
8#
9#  This file is part of TSPSG.
10#
11######################################################################
12
13# Common rules
14#l10n.files = l10n/*.qm
15#share.files =
16docs.files = COPYING ChangeLog.txt README.txt INSTALL.txt
17INSTALLS += target share docs # l10n
18
19# For *nix:
20#   - executable goes to /usr/bin
21#   - COPYING and README go to /usr/share/TSPSG
22#   - translations go to /usr/share/TSPSG/l10n
23#   - docs go to /usr/share/doc/TSPSG-x.x.x
24unix:!macx:!symbian {
25        isEmpty(PREFIX) {
26                PREFIX = /usr
27        }
28        CONFIG(release, debug|release) {
29                DEFINES += PATH_L10N=\\\"$$PREFIX/share/TSPSG/l10n\\\"
30                DEFINES += PATH_DOCS=\\\"$$PREFIX/share/TSPSG/docs\\\"
31        }
32
33        target.path = $$PREFIX/bin
34        share.path = $$PREFIX/share/TSPSG
35#       l10n.path = $$PREFIX/share/TSPSG/l10n
36        docs.path = $$PREFIX/share/doc/TSPSG-$$VERSION
37        desktop.files = resources/tspsg.desktop
38        desktop.path = $$PREFIX/share/applications
39        icon.files = resources/tspsg.png
40        icon.path = $$PREFIX/share/pixmaps
41        INSTALLS += desktop icon
42}
43
44# TODO: MacOSX
45macx {
46}
47
48# For win32: everything goes to "%PROGRAMFILES%\TSPSG" and subfolders.
49win32 {
50        isEmpty(PREFIX) {
51                PREFIX = "$$(PROGRAMFILES)"
52        }
53
54        share.files = $$[QT_INSTALL_BINS]/QtCore$${D}4.dll \
55                $$[QT_INSTALL_BINS]/QtGui$${D}4.dll
56        !nosvg {
57                share.files += $$[QT_INSTALL_BINS]/QtSvg$${D}4.dll
58        }
59#       l10n.files += $$[QT_INSTALL_TRANSLATIONS]/*.qm
60        win32-g++ {
61                share.files += $$[QT_INSTALL_BINS]/mingwm10.dll \
62                        $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll
63        }
64#       iconengines.files = $$[QT_INSTALL_PLUGINS]/iconengines/qsvgicon$${D}4.dll
65#       iconengines.path = $$PREFIX/TSPSG/iconengines
66        imageformats.files = $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${D}4.dll \
67                $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${D}4.dll
68        imageformats.path = $$PREFIX/TSPSG/imageformats
69        INSTALLS += imageformats # iconengines
70}
71
72# For wince: we are deploying to \Program Files\TSPSG.
73wince* {
74        isEmpty(PREFIX) {
75                PREFIX = "\\Program Files"
76        }
77        share.sources = $$share.files
78#       l10n.sources = $$l10n.files \
79#               $$[QT_INSTALL_TRANSLATIONS]/*.qm
80        docs.sources = $$docs.files
81
82        DEPLOYMENT += target share docs # l10n
83#       DEPLOYMENT_PLUGIN += qjpeg qtiff qsvgicon
84}
85
86# win32 and wince common
87win* {
88        target.path = $$PREFIX/TSPSG
89        share.path = $$PREFIX/TSPSG
90#       l10n.path = $$PREFIX/TSPSG/l10n
91        docs.path = $$PREFIX/TSPSG
92}
93
94# Symbian
95symbian {
96        # qmake for Symbian (as of Qt 4.6.2) has a bug: file masks doesn't work, so we need to specify all files manually
97        share.sources = $$share.files
98#       l10n.sources = $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \
99#               $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm \
100#               l10n/tspsg_en.qm l10n/tspsg_ru.qm l10n/tspsg_uk.qm
101#       l10n.path = l10n
102        docs.sources = $$docs.files
103        docs.pkg_prerules = \
104                "\"README.txt\" - \"\", FILETEXT, TEXTCONTINUE" \
105                "\"COPYING\" - \"\", FILETEXT, TEXTEXIT"
106        DEPLOYMENT += share docs # l10n
107#       DEPLOYMENT_PLUGIN += qjpeg qtiff qsvgicon
108
109        ICON = resources/tspsg.svg
110
111        appinfo = \
112                "$$LITERAL_HASH{\"TSPSG\"},(0xEb9dce0e),$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE"
113        vendorinfo = \
114                "%{\"l-homes.org\"}" \
115                ":\"l-homes.org\""
116        default_deployment.pkg_prerules = appinfo vendorinfo
117        DEPLOYMENT.installer_header = "$${LITERAL_HASH}{\"TSPSG Installer\"},(0xA000D7CE),1,0,0"
118}
Note: See TracBrowser for help on using the repository browser.